
    Connect to DSMR meter

Mix.install([
  {:dsmr, "~> 1.0"},
  {:kino, "~> 0.12.0"},
  {:kino_vega_lite, "~> 0.1.10"}
])

alias VegaLite, as: Vl
Configuration
Configure your DSMR meter connection settings:
# Enter your DSMR meter's network address
# Examples:
#   - WiFi P1 adapter: "192.168.1.100"
#   - Hostname: "dsmr-meter.local"
meter_host = Kino.Input.text("Meter Host/IP", default: "192.168.1.100")

# Most P1-to-WiFi adapters use port 23 (Telnet)
# Some may use different ports - check your adapter's documentation
meter_port = Kino.Input.number("Meter Port", default: 23)

Kino.Layout.grid([meter_host, meter_port], columns: 2)
Define Meter GenServer
defmodule Meter do
  use GenServer

  require Logger

  @connect_timeout 5000
  @recv_timeout 5000

  def listen(fun, opts) do
    GenServer.start_link(__MODULE__, {fun, opts}, name: __MODULE__)
  end

  @impl true
  def init({fun, opts}) do
    {:ok, host} = parse_host(opts[:host])

    state = %{socket: nil, fun: fun, lines: ""}
    {:ok, state, {:continue, host: host, port: opts[:port]}}
  end

  @impl true
  def handle_continue(opts, state) do
    socket_opts = [:binary, active: false, packet: :line]

    case :gen_tcp.connect(opts[:host], opts[:port], socket_opts, @connect_timeout) do
      {:ok, socket} ->
        send(self(), :recv_loop)
        {:noreply, %{state | socket: socket}}

      {:error, reason} ->
        Logger.error("Unable to connect to meter - reason: #{inspect(reason)}")
        {:stop, :normal, state}
    end
  end

  @impl true
  def handle_info(:recv_loop, state) do
    case :gen_tcp.recv(state.socket, 0, @recv_timeout) do
      {:ok, line} ->
        send(self(), {:recv_line, line})
        send(self(), :recv_loop)
        {:noreply, state}

      {:error, reason} ->
        Logger.error("Unable to connect to remote TCP socket - reason: #{inspect(reason)}")
        {:stop, :normal, state}
    end
  end

  @impl true
  def handle_info({:recv_line, "!" <> _ = line}, state) do
    if state.lines != "" do
      send(self(), {:telegram, state.lines <> line})
    end

    {:noreply, %{state | lines: ""}}
  end

  @impl true
  def handle_info({:recv_line, "/" <> _ = line}, %{lines: ""} = state) do
    # Ignore partially received telegram when starting to read from socket.
    {:noreply, %{state | lines: line}}
  end

  @impl true
  def handle_info({:recv_line, _line}, %{lines: ""} = state) do
    # Ignore partially received telegram when starting to read from socket.
    {:noreply, state}
  end

  @impl true
  def handle_info({:recv_line, line}, state) do
    {:noreply, %{state | lines: state.lines <> line}}
  end

  @impl true
  def handle_info({:telegram, raw}, state) do
    case DSMR.parse(raw) do
      {:ok, telegram} ->
        Logger.info("Received telegram - #{telegram.checksum}")
        state.fun.(telegram)

      {:error, reason} ->
        Logger.error("Unable to parse telegram - reason: #{inspect(reason)}")
    end

    {:noreply, state}
  end

  defp parse_host(host) when is_binary(host) do
    parse_host(String.to_charlist(host))
  end

  defp parse_host(host) do
    case :inet.parse_address(host) do
      {:ok, ip} -> {:ok, ip}
      {:error, :einval} -> {:ok, host}
    end
  end
end
Visualize Electricity Usage
Create a real-time plot showing electricity delivered and returned to the grid:
usage_plot =
  Vl.new(width: 600, height: 400, padding: 20)
  |> Vl.repeat(
    [layer: ["delivered", "returned"]],
    Vl.new()
    |> Vl.mark(:line)
    |> Vl.encode_field(:x, "date", type: :temporal, title: "Measurement")
    |> Vl.encode_repeat(:y, :layer, type: :quantitative, title: "Electricity Usage (kW)")
    |> Vl.encode(:color, datum: [repeat: :layer], type: :nominal)
  )
  |> Kino.VegaLite.new()
Connect to Meter
Start listening to the meter and update the plot with each telegram:
{:ok, pid} =
  Meter.listen(
    fn telegram ->
      # Extract measurement values
      delivered =
        case telegram.electricity_currently_delivered do
          %{value: %Decimal{} = d} -> Decimal.to_float(d)
          %{value: v} when is_float(v) -> v
          _ -> 0.0
        end

      returned =
        case telegram.electricity_currently_returned do
          %{value: %Decimal{} = d} -> Decimal.to_float(d)
          %{value: v} when is_float(v) -> v
          _ -> 0.0
        end

      # Extract timestamp
      timestamp =
        case telegram.measured_at do
          %{value: dt} -> dt
          dt when is_struct(dt, NaiveDateTime) -> dt
          _ -> NaiveDateTime.utc_now()
        end

      # Push to chart
      Kino.VegaLite.push(
        usage_plot,
        %{date: timestamp, delivered: delivered, returned: returned},
        window: 300
      )
    end,
    host: Kino.Input.read(meter_host),
    port: Kino.Input.read(meter_port)
  )
Stop Listening
When you're done, stop the meter listener:
GenServer.stop(pid, :shutdown)
Example: Simple Logger
Alternatively, you can just log telegram data without visualization:
{:ok, pid} =
  Meter.listen(
    fn telegram ->
      IO.puts("""
      ========================================
      Timestamp: #{inspect(telegram.measured_at)}
      Version: DSMR #{telegram.version}
      Currently Delivered: #{inspect(telegram.electricity_currently_delivered)}
      Currently Returned: #{inspect(telegram.electricity_currently_returned)}
      Cumulative Delivered (T1): #{inspect(telegram.electricity_delivered_1)}
      Cumulative Delivered (T2): #{inspect(telegram.electricity_delivered_2)}
      Gas: #{inspect(List.first(telegram.mbus_devices))}
      ========================================
      """)
    end,
    host: Kino.Input.read(meter_host),
    port: Kino.Input.read(meter_port)
  )

# Stop when done
# GenServer.stop(pid, :shutdown)


  

    Dummy Smart Meter

Mix.install([
  {:dsmr, "~> 1.0"},
  {:kino, "~> 0.12.0"},
  {:kino_vega_lite, "~> 0.1.10"}
])

alias VegaLite, as: Vl
Configuration
Configure the dummy meter settings:
# Emission interval in milliseconds (default: 1000ms = 1 second)
emission_interval = Kino.Input.number("Emission Interval (ms)", default: 1000)

# Time acceleration factor (1 = real-time, 60 = 1 minute per second, etc.)
time_acceleration = Kino.Input.number("Time Acceleration Factor", default: 60)

# TCP server port for P1 clients to connect
server_port = Kino.Input.number("TCP Server Port", default: 8000)

Kino.Layout.grid([emission_interval, time_acceleration, server_port], columns: 3)
Define TCP Server
defmodule TCPServer do
  use GenServer

  require Logger

  def start_link(opts) do
    GenServer.start_link(__MODULE__, opts, name: __MODULE__)
  end

  def broadcast(telegram_string) do
    GenServer.cast(__MODULE__, {:broadcast, telegram_string})
  end

  @impl true
  def init(opts) do
    port = opts[:port] || 8000

    {:ok, listen_socket} =
      :gen_tcp.listen(port, [
        :binary,
        active: false,
        reuseaddr: true,
        packet: :line
      ])

    Logger.info("TCP server listening on port #{port}")

    # Start accepting connections
    send(self(), :accept)

    {:ok, %{listen_socket: listen_socket, clients: []}}
  end

  @impl true
  def handle_info(:accept, state) do
    case :gen_tcp.accept(state.listen_socket) do
      {:ok, client_socket} ->
        Logger.info("Client connected: #{inspect(client_socket)}")
        # Continue accepting more connections
        send(self(), :accept)
        {:noreply, %{state | clients: [client_socket | state.clients]}}

      {:error, reason} ->
        Logger.error("Failed to accept connection: #{inspect(reason)}")
        {:noreply, state}
    end
  end

  @impl true
  def handle_cast({:broadcast, telegram_string}, state) do
    # Send telegram to all connected clients
    active_clients =
      Enum.filter(state.clients, fn socket ->
        case :gen_tcp.send(socket, telegram_string) do
          :ok ->
            true

          {:error, reason} ->
            Logger.warning("Failed to send to client: #{inspect(reason)}")
            :gen_tcp.close(socket)
            false
        end
      end)

    {:noreply, %{state | clients: active_clients}}
  end
end
Define Dummy Meter GenServer
defmodule DummyMeter do
  use GenServer

  require Logger

  @moduledoc """
  A dummy smart meter that emits telegrams with wave-pattern electricity usage.
  More electricity is consumed during the day (8am-10pm) than at night.
  """

  def start_link(opts) do
    GenServer.start_link(__MODULE__, opts, name: __MODULE__)
  end

  def stop do
    GenServer.stop(__MODULE__)
  end

  @impl true
  def init(opts) do
    interval = opts[:interval] || 1000
    acceleration = opts[:acceleration] || 1
    callback = opts[:callback]
    tcp_enabled = opts[:tcp_enabled] || false

    # Initial state with cumulative counters
    state = %{
      interval: interval,
      acceleration: acceleration,
      callback: callback,
      tcp_enabled: tcp_enabled,
      virtual_time: NaiveDateTime.utc_now(),
      electricity_delivered_1: 1234.567,
      electricity_delivered_2: 2345.678,
      electricity_returned_1: 123.456,
      electricity_returned_2: 234.567,
      gas_delivered: 987.654
    }

    # Start emission loop
    schedule_emission(0)

    {:ok, state}
  end

  @impl true
  def handle_info(:emit_telegram, state) do
    # Advance virtual time
    virtual_time =
      NaiveDateTime.add(state.virtual_time, state.acceleration, :second)

    # Calculate current power based on time of day (wave pattern)
    hour = virtual_time.hour
    minute = virtual_time.minute

    # Calculate time as fraction of day (0.0 to 1.0)
    time_of_day = (hour * 60 + minute) / (24 * 60)

    # Wave pattern: peak at 18:00 (0.75), low at 3:00 (0.125)
    # Using shifted cosine wave
    phase = (time_of_day - 0.75) * 2 * :math.pi()
    wave = (:math.cos(phase) + 1) / 2

    # Map wave to power range: 0.2 kW (night) to 2.5 kW (day peak)
    base_power = 0.2
    peak_power = 2.5
    current_power = base_power + wave * (peak_power - base_power)

    # Add some randomness (±10%)
    noise = :rand.uniform() * 0.2 - 0.1
    current_power = current_power * (1 + noise)
    current_power = max(0.0, current_power)

    # Update cumulative counters (add power consumption for this interval)
    # Power is in kW, interval is in seconds, so kWh = kW * (seconds / 3600)
    energy_increment = current_power * (state.interval / 1000 / 3600)

    # Randomly distribute between tariff 1 and 2 (day/night)
    {delivered_1, delivered_2} =
      if hour >= 23 or hour < 7 do
        # Night tariff (T2)
        {state.electricity_delivered_1, state.electricity_delivered_2 + energy_increment}
      else
        # Day tariff (T1)
        {state.electricity_delivered_1 + energy_increment, state.electricity_delivered_2}
      end

    # Occasionally return power (solar panels)
    {current_returned, returned_1, returned_2} =
      if hour >= 10 and hour < 17 and :rand.uniform() < 0.3 do
        returned_power = :rand.uniform() * 1.5
        returned_increment = returned_power * (state.interval / 1000 / 3600)

        {returned_power, state.electricity_returned_1 + returned_increment,
         state.electricity_returned_2}
      else
        {0.0, state.electricity_returned_1, state.electricity_returned_2}
      end

    # Gas increments slowly (typical usage: ~5 m³/day)
    gas_increment =
      if rem(virtual_time.hour, 1) == 0 and virtual_time.minute == 0 do
        # Update gas once per hour
        0.2
      else
        0.0
      end

    gas_delivered = state.gas_delivered + gas_increment

    # Build telegram
    telegram = %DSMR.Telegram{
      header: "ISk5\\2MT382-1000",
      version: "50",
      measured_at: %DSMR.Timestamp{
        value: virtual_time,
        dst: "W"
      },
      equipment_id: "4530303437303030303037363330383137",
      electricity_delivered_1: %DSMR.Measurement{
        value: Float.round(delivered_1, 3),
        unit: "kWh"
      },
      electricity_delivered_2: %DSMR.Measurement{
        value: Float.round(delivered_2, 3),
        unit: "kWh"
      },
      electricity_returned_1: %DSMR.Measurement{
        value: Float.round(returned_1, 3),
        unit: "kWh"
      },
      electricity_returned_2: %DSMR.Measurement{
        value: Float.round(returned_2, 3),
        unit: "kWh"
      },
      electricity_tariff_indicator: if(hour >= 23 or hour < 7, do: "0002", else: "0001"),
      electricity_currently_delivered: %DSMR.Measurement{
        value: Float.round(current_power, 3),
        unit: "kW"
      },
      electricity_currently_returned: %DSMR.Measurement{
        value: Float.round(current_returned, 3),
        unit: "kW"
      },
      power_failures_count: "0",
      power_failures_long_count: "0",
      voltage_sags_l1_count: "0",
      voltage_swells_l1_count: "0",
      mbus_devices: [
        %DSMR.MBusDevice{
          channel: 1,
          device_type: "003",
          equipment_id: "4730303339303031373434313430323137",
          last_reading_measured_at: %DSMR.Timestamp{
            value: virtual_time,
            dst: "W"
          },
          last_reading_value: %DSMR.Measurement{
            value: Float.round(gas_delivered, 3),
            unit: "m3"
          }
        }
      ],
      checksum: "0000"
    }

    # Calculate actual checksum
    telegram_string = DSMR.Telegram.to_string(%{telegram | checksum: "0000"})
    checksum = calculate_checksum(telegram_string)
    telegram = %{telegram | checksum: checksum}
    final_telegram_string = DSMR.Telegram.to_string(telegram)

    # Emit telegram via callback
    Logger.info("Emitting telegram for #{virtual_time}")
    state.callback.(telegram)

    # Broadcast to TCP clients if enabled
    if state.tcp_enabled do
      TCPServer.broadcast(final_telegram_string)
    end

    # Schedule next emission
    schedule_emission(state.interval)

    {:noreply,
     %{
       state
       | virtual_time: virtual_time,
         electricity_delivered_1: delivered_1,
         electricity_delivered_2: delivered_2,
         electricity_returned_1: returned_1,
         electricity_returned_2: returned_2,
         gas_delivered: gas_delivered
     }}
  end

  defp schedule_emission(interval) do
    Process.send_after(self(), :emit_telegram, interval)
  end

  defp calculate_checksum(telegram_string) do
    # Extract data between / and ! (inclusive of !)
    data =
      telegram_string
      |> String.split("/", parts: 2)
      |> List.last()

    # Calculate CRC16
    crc = DSMR.CRC16.calculate(data)

    # Return as uppercase hex string
    crc
    |> Integer.to_string(16)
    |> String.pad_leading(4, "0")
    |> String.upcase()
  end
end
Start TCP Server
Start the TCP server to allow P1 clients to connect:
{:ok, tcp_server} = TCPServer.start_link(port: Kino.Input.read(server_port))
Visualize Electricity Usage
Create a real-time plot showing electricity delivered and returned:
usage_plot =
  Vl.new(width: 600, height: 400, padding: 20)
  |> Vl.repeat(
    [layer: ["delivered", "returned"]],
    Vl.new()
    |> Vl.mark(:line)
    |> Vl.encode_field(:x, "date", type: :temporal, title: "Time")
    |> Vl.encode_repeat(:y, :layer, type: :quantitative, title: "Electricity (kW)")
    |> Vl.encode(:color, datum: [repeat: :layer], type: :nominal)
  )
  |> Kino.VegaLite.new()
Start Dummy Meter
Start the dummy meter and watch the wave pattern emerge. The meter will broadcast telegrams to all connected P1 clients:
{:ok, meter_pid} =
  DummyMeter.start_link(
    interval: Kino.Input.read(emission_interval),
    acceleration: Kino.Input.read(time_acceleration),
    tcp_enabled: true,
    callback: fn telegram ->
      # Extract current power
      delivered = telegram.electricity_currently_delivered.value
      returned = telegram.electricity_currently_returned.value
      timestamp = telegram.measured_at.value

      # Push to chart
      Kino.VegaLite.push(
        usage_plot,
        %{date: timestamp, delivered: delivered, returned: returned},
        window: 300
      )
    end
  )
Connect with P1 Client
You can now connect to the dummy meter from another Livebook or application using the existing connect_to_dsmr_meter.livemd example. Just use localhost as the host and the configured port (default: 8000).
Example connection settings:
	Host: localhost
	Port: 8000 (or your configured port)

Stop Meter and Server
When you're done, stop the dummy meter and TCP server:
DummyMeter.stop()
GenServer.stop(tcp_server)
Alternative: Log Telegrams Only
If you only want to log telegram data without TCP broadcasting:
{:ok, meter_pid} =
  DummyMeter.start_link(
    interval: Kino.Input.read(emission_interval),
    acceleration: Kino.Input.read(time_acceleration),
    tcp_enabled: false,
    callback: fn telegram ->
      IO.puts("""
      ========================================
      Timestamp: #{inspect(telegram.measured_at.value)}
      Currently Delivered: #{telegram.electricity_currently_delivered.value} kW
      Currently Returned: #{telegram.electricity_currently_returned.value} kW
      Cumulative T1: #{telegram.electricity_delivered_1.value} kWh
      Cumulative T2: #{telegram.electricity_delivered_2.value} kWh
      Gas: #{List.first(telegram.mbus_devices).last_reading_value.value} m³
      ========================================
      """)
    end
  )

# Stop when done
# DummyMeter.stop()
Alternative: Export as Raw DSMR Format
You can also print telegrams as raw DSMR strings:
{:ok, meter_pid} =
  DummyMeter.start_link(
    interval: Kino.Input.read(emission_interval),
    acceleration: Kino.Input.read(time_acceleration),
    tcp_enabled: false,
    callback: fn telegram ->
      telegram
      |> DSMR.Telegram.to_string()
      |> IO.puts()
    end
  )

# Stop when done
# DummyMeter.stop()

A library for parsing Dutch Smart Meter Requirements (DSMR) telegram data.
DSMR is the standardized protocol used by smart energy meters in the Netherlands, Belgium, and Luxembourg. These smart meters are installed in homes and businesses to measure electricity and gas consumption in real-time.
Smart meters continuously broadcast "telegrams" - structured data packets containing:
	Current and cumulative electricity usage (delivered and returned to grid)
	Gas consumption readings
	Voltage and current measurements per phase
	Power failure logs and quality statistics
	Additional M-Bus connected devices (water, thermal, etc.)

This library parses these telegrams into Elixir structs, making it easy to build energy monitoring applications, home automation systems, or analytics dashboards.
Installation
Add dsmr to your list of dependencies in mix.exs:
def deps do
  [
    {:dsmr, "~> 1.0"},
    {:decimal, "~> 3.1"} # Optional: Required only if you want to use floats: :decimals option for arbitrary precision
  ]
end
By default, measurement values are returned as native floats. To use high-precision %Decimal{} structs instead, add the Decimal dependency and pass the floats: :decimals option to DSMR.parse/2.
Supported DSMR Versions
The parser supports DSMR 2.2, 3.0, 4.x, and 5.x telegrams. Version-specific
fields are optional on %DSMR.Telegram{} and remain nil when they are not
present in the input.
Usage
telegram =
  # String is formatted in separate lines for readability.
  Enum.join([
    "/KFM5KAIFA-METER\r\n",
    "\r\n",
    "1-3:0.2.8(42)\r\n",
    "0-0:1.0.0(161113205757W)\r\n",
    "0-0:96.1.1(3960221976967177082151037881335713)\r\n",
    "1-0:1.8.1(001581.123*kWh)\r\n",
    "1-0:1.8.2(001435.706*kWh)\r\n",
    "1-0:2.8.1(000000.000*kWh)\r\n",
    "1-0:2.8.2(000000.000*kWh)\r\n",
    "0-0:96.14.0(0002)\r\n",
    "1-0:1.7.0(02.027*kW)\r\n",
    "1-0:2.7.0(00.000*kW)\r\n",
    "0-0:96.7.21(00015)\r\n",
    "0-0:96.7.9(00007)\r\n",
    "1-0:99.97.0(3)(0-0:96.7.19)(000104180320W)(0000237126*s)(000101000001W)",
    "(2147583646*s)(000102000003W)(2317482647*s)\r\n",
    "1-0:32.32.0(00000)\r\n",
    "1-0:52.32.0(00000)\r\n",
    "1-0:72.32.0(00000)\r\n",
    "1-0:32.36.0(00000)\r\n",
    "1-0:52.36.0(00000)\r\n",
    "1-0:72.36.0(00000)\r\n",
    "0-0:96.13.1()\r\n",
    "0-0:96.13.0()\r\n",
    "1-0:31.7.0(000*A)\r\n",
    "1-0:51.7.0(006*A)\r\n",
    "1-0:71.7.0(002*A)\r\n",
    "1-0:21.7.0(00.170*kW)\r\n",
    "1-0:22.7.0(00.000*kW)\r\n",
    "1-0:41.7.0(01.247*kW)\r\n",
    "1-0:42.7.0(00.000*kW)\r\n",
    "1-0:61.7.0(00.209*kW)\r\n",
    "1-0:62.7.0(00.000*kW)\r\n",
    "0-1:24.1.0(003)\r\n",
    "0-1:96.1.0(4819243993373755377509728609491464)\r\n",
    "0-1:24.2.1(161129200000W)(00981.443*m3)\r\n",
    "!6796\r\n"
  ])

{:ok, parsed} = DSMR.parse(telegram)

parsed.version
#=> "42"

parsed.electricity_delivered_1
#=> %DSMR.Measurement{unit: "kWh", value: 1581.123}
Parser Options
DSMR.parse/2 accepts these options:
	Option	Values	Default	Description
	:checksum	true / false	true	Validates the CRC16 checksum when enabled.
	:floats	:native / :decimals	:native	Returns decimal values as native floats or %Decimal{} structs.

Examples:
# Skip checksum validation
DSMR.parse(telegram, checksum: false)

# Tolerate common deviations from the standard (LF-only line endings,
# power failure log count mismatches) seen on real-world setups
DSMR.parse(data, lenient: true)

# Use Decimal for precise calculations
DSMR.parse(telegram, floats: :decimals)
Available Telegram Fields
DSMR.parse/2 returns a %DSMR.Telegram{} struct. Common fields include:
Header and metadata
	header - Meter manufacturer and model
	checksum - CRC16 checksum
	version - DSMR protocol version
	measured_at - Telegram timestamp
	equipment_id - Unique meter identifier

Electricity measurements
	electricity_delivered_1 / electricity_delivered_2 - Cumulative consumption (tariff 1/2)
	electricity_returned_1 / electricity_returned_2 - Cumulative return to grid (tariff 1/2)
	electricity_tariff_indicator - Current active tariff
	electricity_currently_delivered / electricity_currently_returned - Instantaneous power

Per-phase measurements
	currently_delivered_l1/l2/l3 - Power delivered per phase
	currently_returned_l1/l2/l3 - Power returned per phase
	voltage_l1/l2/l3 - Voltage per phase
	phase_power_current_l1/l2/l3 - Current per phase

Power quality
	power_failures_count / power_failures_long_count - Failure counters
	power_failures_log - Timestamped log of power failures
	voltage_sags_l1/l2/l3_count / voltage_swells_l1/l2/l3_count - Quality events

M-Bus devices
	mbus_devices - Connected gas, water, heat, or other meters

Unknown OBIS codes are collected in unknown_fields as {obis_tuple, value}
pairs. They are preserved instead of rejected.
See full documentation for detailed field descriptions and types.
Decoding Values
Parsed telegrams keep values exactly as they appear in the telegram, so
serialization stays lossless. Two helpers decode them into more useful forms:
# equipment_id, text_message, and M-Bus equipment ids are hex-encoded ASCII
DSMR.Telegram.decode_octet_string(parsed.equipment_id)
#=> {:ok, "K8EG004046395507"}

# Timestamps are Dutch local time; the DST marker gives the UTC offset
DSMR.Timestamp.to_datetime(parsed.measured_at)
#=> {:ok, ~U[2016-11-13 19:57:57Z]}
to_datetime/1 returns {:error, :missing_dst} for timestamps without a DST
marker (DSMR 2.2/3.0), as their UTC offset is ambiguous.
Serialization
Use DSMR.Telegram.to_string/1 to convert a telegram struct back to its string
representation. Fields with nil or empty string values are omitted.
telegram = %DSMR.Telegram{
  header: "KFM5KAIFA-METER",
  checksum: "6796",
  version: "42",
  measured_at: %DSMR.Timestamp{
    value: ~N[2016-11-13 20:57:57],
    dst: "W"
  },
  electricity_delivered_1: %DSMR.Measurement{value: Decimal.new("1581.123"), unit: "kWh"}
}

DSMR.Telegram.to_string(telegram)
#=> "/KFM5KAIFA-METER\r\n\r\n1-3:0.2.8(42)\r\n0-0:1.0.0(161113205757W)\r\n1-0:1.8.1(001581.123*kWh)\r\n!6796\r\n"
Error Handling
The parser returns {:error, reason} tuples for invalid data.
DSMR.parse("invalid data")
#=> {:error, %DSMR.ParseError{message: "checksum delimiter '!' not found"}}

{:error, %DSMR.ChecksumError{}} = DSMR.parse("/HEADER\r\n!FFFF\r\n")
Use DSMR.parse!/2 when invalid input should raise instead of returning an
error tuple.
Getting Real Telegram Data
Smart meters typically expose telegram data through a serial P1 port or through
a P1-to-network adapter. This package only parses telegrams; collecting bytes
from the meter is handled separately.
See the included Livebook example for
a GenServer that:
	Connects to a meter via TCP (common with WiFi P1 adapters)
	Buffers incoming lines and assembles complete telegrams
	Parses telegrams and visualizes usage

For serial port connections, use libraries like Circuits.UART.
Internals
DSMR uses a two-stage parser built on Erlang's leex and yecc.
Stage 1: Lexical Analysis (leex)
The lexer (src/dsmr_lexer.xrl) turns telegram text into tokens:
	OBIS codes such as 1-0:1.8.1
	Timestamps such as 161113205757W
	Measurements such as 001581.123*kWh
	Headers and checksums

The lexer also extracts the M-Bus channel from OBIS codes.
Stage 2: Parsing (yecc)
The parser (src/dsmr_parser.yrl) maps tokens into a %DSMR.Telegram{}:
object -> obis attributes : map_obis_to_field('$1', '$2').
attribute -> '(' value ')' : '$2'.
value -> float '*' string : extract_measurement('$1', '$3').
OBIS mappings live in DSMR.OBIS. The parser calls that module to map known
codes to telegram fields.
Special cases are handled directly in the parser:
	M-Bus fields are grouped by channel.
	Power failure logs are parsed as variable-length event lists.
	Unknown OBIS codes are collected in unknown_fields.

        Parses a telegram.



    


    
      
        parse!(string, options \\ [])

      


        Parses a telegram and returns a DSMR.Telegram struct.

          @type parse_opt() ::
  {:checksum, boolean()}
  | {:floats, :native | :decimals}
  | {:lenient, boolean()}

          @spec parse(binary(), [parse_opt()]) ::
  {:ok, DSMR.Telegram.t()}
  | {:error, DSMR.ParseError.t() | DSMR.ChecksumError.t()}


      


Parses a telegram.
Returns {:ok, telegram} on success. Invalid input returns
{:error, %DSMR.ParseError{}}; checksum mismatches return
{:error, %DSMR.ChecksumError{}}.
Options
	:checksum - validates the CRC16 checksum when true. Defaults to true.

	:floats - controls how decimal numbers are parsed:
	:native - returns native floats. This is the default.
	:decimals - returns %Decimal{} structs for decimal values.


	:lenient - tolerates common deviations from the DSMR standard seen in
real-world setups when true. Defaults to false.
	LF-only line endings (e.g. from serial readers that strip carriage
returns) are converted back to CRLF before parsing and checksum
validation.
	Power failure logs whose declared event count does not match the
number of events (seen on some meters) are accepted; the events
actually present are used.

          @spec parse!(binary(), [parse_opt()]) :: DSMR.Telegram.t() | no_return()


      


Parses a telegram and returns a DSMR.Telegram struct.
This is the raising variant of parse/2.

  


        

      


  

    
DSMR.MBusDevice 
    



      
A device connected through the meter's M-Bus interface.
DSMR telegrams commonly use M-Bus entries for gas meters, but the same shape
can represent water, heat, or other connected meters. Only channel is
required; the remaining fields are present when the telegram includes the
corresponding OBIS codes.

          @type t() :: %DSMR.MBusDevice{
  channel: non_neg_integer(),
  device_type: String.t() | nil,
  equipment_id: String.t() | nil,
  last_reading_measured_at: DSMR.Timestamp.t() | nil,
  last_reading_value: DSMR.Measurement.t() | nil,
  valve_position: String.t() | nil
}


      



  


        

      


  

    
DSMR.Measurement 
    



      
A numeric value with a DSMR unit.
Measurements are used for electricity, gas, voltage, current, and duration
values. Values are parsed as native numbers by default. When DSMR.parse/2
is called with floats: :decimals, decimal values are returned as
%Decimal{} structs.

        raw holds the exact numeric text from the telegram (e.g. "000123.456")
so that serialization can reproduce the original padding and precision.
It is nil for measurements constructed by hand.

          @type t() :: %DSMR.Measurement{
  raw: String.t() | nil,
  unit: String.t(),
  value: integer() | float() | Decimal.t()
}


      


raw holds the exact numeric text from the telegram (e.g. "000123.456")
so that serialization can reproduce the original padding and precision.
It is nil for measurements constructed by hand.

OBIS code mappings used by the parser and serializer.
OBIS codes identify the values contained in a DSMR telegram. This module maps
known codes to %DSMR.Telegram{} fields and exposes the reverse mapping used
by DSMR.Telegram.to_string/1.

        Spec-defined measurement value format as {integer_digits, decimals}.

        Returns all field-to-OBIS mappings as a map.



    


    
      
        field_definitions()

      


        Returns the ordered field definitions: {field, {obis_string, value_type}}.

        Returns the ordered list of telegram fields for serialization.



    


    
      
        get_field(obis_list)

      


        Returns the field name for a given OBIS code list.



    


    
      
        get_format(field)

      


        Returns the spec-defined measurement format for a field, or nil when the
field is not a measurement.



    


    
      
        get_obis(arg1)

      


        Returns the OBIS code string for a given telegram field.

          @type format() :: {non_neg_integer(), non_neg_integer()}


      


Spec-defined measurement value format as {integer_digits, decimals}.
For example the DSMR F9(3,3) energy register format is {6, 3}:
six integer digits and three decimals.

          @spec all_mappings() :: %{required(atom()) => String.t()}


      


Returns all field-to-OBIS mappings as a map.

          @spec field_definitions() :: [
  {atom(),
   {String.t() | nil,
    :string | :timestamp | {:measurement, format()} | :power_failures_log}}
]


      


Returns the ordered field definitions: {field, {obis_string, value_type}}.
This is the single source of truth for telegram fields; DSMR.Telegram
derives its struct and typespec from it at compile time.

          @spec field_order() :: [atom()]


      


Returns the ordered list of telegram fields for serialization.
The order matches the DSMR specification and is used when converting
a Telegram struct to its string representation.
Examples
iex> fields = DSMR.OBIS.field_order()
iex> hd(fields)
:version
iex> :electricity_delivered_1 in fields
true

          @spec get_field([non_neg_integer()]) :: atom() | nil


      


Returns the field name for a given OBIS code list.
Used by the parser to map OBIS codes to struct fields.
This function is called from Erlang code in dsmr_parser.yrl.
Examples
iex> DSMR.OBIS.get_field([1, 3, 0, 2, 8])
:version

iex> DSMR.OBIS.get_field([1, 0, 1, 8, 1])
:electricity_delivered_1

iex> DSMR.OBIS.get_field([99, 99, 99, 99, 99])
nil

          @spec get_format(atom()) :: format() | nil


      


Returns the spec-defined measurement format for a field, or nil when the
field is not a measurement.
Examples
iex> DSMR.OBIS.get_format(:voltage_l1)
{3, 1}

iex> DSMR.OBIS.get_format(:version)
nil

          @spec get_obis(atom()) :: String.t() | nil


      


Returns the OBIS code string for a given telegram field.
Used by serialization logic (Telegram.to_string/1).
Examples
iex> DSMR.OBIS.get_obis(:version)
"1-3:0.2.8"

iex> DSMR.OBIS.get_obis(:electricity_delivered_1)
"1-0:1.8.1"

  


        

      


  

    
DSMR.Telegram 
    



      
A parsed DSMR telegram.
A telegram contains the values broadcast by a smart meter at a point in time.
Different DSMR versions expose different fields, so most fields are optional
and remain nil when the input does not contain the corresponding OBIS code.
Unknown OBIS codes are preserved in unknown_fields instead of being rejected.
This keeps parsing tolerant of regional extensions and meter-specific fields.

        decode_octet_string(value)

      


        Decodes a hex-encoded octet-string value to its ASCII representation.



    


    
      
        to_string(telegram)

      


        Converts a Telegram struct back to its string representation.

          @type maybe(type) :: type | nil

          @type obis_t() ::
  {non_neg_integer(), non_neg_integer(), non_neg_integer(), non_neg_integer(),
   non_neg_integer()}

          @type obj_t() :: {obis_t(), value_t() | [value_t()]}

          @type power_failure_event_t() :: [DSMR.Timestamp.t() | DSMR.Measurement.t()]

          @type t() :: %DSMR.Telegram{
  actual_switch_position: maybe(String.t()),
  actual_threshold_electricity: maybe(DSMR.Measurement.t()),
  checksum: String.t(),
  currently_delivered_l1: maybe(DSMR.Measurement.t()),
  currently_delivered_l2: maybe(DSMR.Measurement.t()),
  currently_delivered_l3: maybe(DSMR.Measurement.t()),
  currently_returned_l1: maybe(DSMR.Measurement.t()),
  currently_returned_l2: maybe(DSMR.Measurement.t()),
  currently_returned_l3: maybe(DSMR.Measurement.t()),
  electricity_currently_delivered: maybe(DSMR.Measurement.t()),
  electricity_currently_returned: maybe(DSMR.Measurement.t()),
  electricity_delivered_1: maybe(DSMR.Measurement.t()),
  electricity_delivered_2: maybe(DSMR.Measurement.t()),
  electricity_returned_1: maybe(DSMR.Measurement.t()),
  electricity_returned_2: maybe(DSMR.Measurement.t()),
  electricity_tariff_indicator: maybe(String.t()),
  equipment_id: maybe(String.t()),
  header: String.t(),
  mbus_devices: [DSMR.MBusDevice.t()],
  measured_at: maybe(DSMR.Timestamp.t()),
  phase_power_current_l1: maybe(DSMR.Measurement.t()),
  phase_power_current_l2: maybe(DSMR.Measurement.t()),
  phase_power_current_l3: maybe(DSMR.Measurement.t()),
  power_failures_count: maybe(String.t()),
  power_failures_log: maybe([power_failure_event_t()]),
  power_failures_long_count: maybe(String.t()),
  text_message: maybe(String.t()),
  text_message_code: maybe(String.t()),
  unknown_fields: [unknown_field_t()],
  version: maybe(String.t()),
  voltage_l1: maybe(DSMR.Measurement.t()),
  voltage_l2: maybe(DSMR.Measurement.t()),
  voltage_l3: maybe(DSMR.Measurement.t()),
  voltage_sags_l1_count: maybe(String.t()),
  voltage_sags_l2_count: maybe(String.t()),
  voltage_sags_l3_count: maybe(String.t()),
  voltage_swells_l1_count: maybe(String.t()),
  voltage_swells_l2_count: maybe(String.t()),
  voltage_swells_l3_count: maybe(String.t())
}

          @type unknown_field_t() :: {obis_t(), value_t() | [value_t()]}

          @type value_t() ::
  String.t()
  | integer()
  | float()
  | Decimal.t()
  | obis_t()
  | DSMR.Timestamp.t()
  | DSMR.Measurement.t()
  | nil

          @spec decode_octet_string(String.t()) :: {:ok, String.t()} | :error


      


Decodes a hex-encoded octet-string value to its ASCII representation.
The DSMR standard encodes octet-string values as hexadecimal ASCII: this
applies to equipment_id, text_message, and DSMR.MBusDevice
equipment ids. Parsed telegrams keep the raw hex value so that
serialization stays lossless; use this function to read the decoded text.
Returns :error when the value is not valid hex.
Examples
iex> DSMR.Telegram.decode_octet_string("4B384547303034303436333935353037")
{:ok, "K8EG004046395507"}

iex> DSMR.Telegram.decode_octet_string("XYZ")
:error

          @spec to_string(t()) :: String.t()


      


Converts a Telegram struct back to its string representation.
Fields with nil or empty string values are omitted.
Examples
iex> telegram = %DSMR.Telegram{
...>   header: "ISk5\\2MT382-1000",
...>   checksum: "5106",
...>   version: "50"
...> }
iex> DSMR.Telegram.to_string(telegram)
"/ISk5\\2MT382-1000\r\n\r\n1-3:0.2.8(50)\r\n!5106\r\n"

  


        

      


  

    
DSMR.Timestamp 
    



      
A DSMR timestamp.
DSMR timestamps contain a naive date and time. Some telegrams also include a
daylight saving time marker: "W" for winter time or "S" for summer time.

        Converts a timestamp to a UTC DateTime.

          @type t() :: %DSMR.Timestamp{dst: binary() | nil, value: NaiveDateTime.t()}

          @spec to_datetime(t()) :: {:ok, DateTime.t()} | {:error, :missing_dst}


      


Converts a timestamp to a UTC DateTime.
DSMR timestamps are Dutch local time; the DST marker disambiguates the UTC
offset ("W" means UTC+1, "S" means UTC+2). The fixed offsets make this
conversion work without a timezone database dependency.
Returns {:error, :missing_dst} for timestamps without a DST marker
(found in DSMR 2.2/3.0 telegrams), as their UTC offset is ambiguous around
the DST transitions.
Examples
iex> DSMR.Timestamp.to_datetime(%DSMR.Timestamp{value: ~N[2017-01-02 19:20:02], dst: "W"})
{:ok, ~U[2017-01-02 18:20:02Z]}

iex> DSMR.Timestamp.to_datetime(%DSMR.Timestamp{value: ~N[2017-07-02 19:20:02], dst: "S"})
{:ok, ~U[2017-07-02 17:20:02Z]}

iex> DSMR.Timestamp.to_datetime(%DSMR.Timestamp{value: ~N[2017-01-02 19:20:02]})
{:error, :missing_dst}

  


        

      


  

    
DSMR.ChecksumError exception
    



      
Raised or returned when a telegram checksum does not match.
Contains the checksum found in the telegram (expected) and the checksum
computed from the telegram contents (actual).

          @type t() :: %DSMR.ChecksumError{
  __exception__: true,
  actual: binary(),
  expected: binary()
}


      



  


        

      


  

    
DSMR.ParseError exception
    



      
Raised or returned when a telegram cannot be parsed.

          @type t() :: %DSMR.ParseError{__exception__: true, message: binary()}

